Výpočet DPH v Exceli
Na DPH v Exceli stačia tri jednoduché vzorce: cena s DPH, cena bez DPH a samotná daň. Naučíš sa ich napísať tak, aby fungovali pre každú sadzbu a vychádzali na centy.
Vyskúšaj si to: Cena s DPH
Do bunky B4 napíš =B1*(1+B2) a stlač Enter. Excel pripočíta k cene bez DPH daň so sadzbou z B2.
| A | B | |
|---|---|---|
| 1 | Cena bez DPH (€) | 250,00 |
| 2 | Sadzba DPH | 23% |
| 3 | ||
| 4 | Cena s DPH (€) |
Klikni na bunku a jej adresa sa vloží do vzorca.
Riešenie: =B1*(1+B2)
1+B2 je 1,23. 250 × 1,23 = 307,50 €. Zátvorka zabezpečí, že sa 1 a sadzba sčítajú pred násobením.
Sadzby DPH na Slovensku
Od 1. januára 2025 platia tri sadzby. Základná je 23 % a platí pre väčšinu tovarov a služieb. Znížená 19 % sa týka napríklad elektriny a časti potravín. Znížená 5 % napríklad kníh, ubytovania, vybraných základných potravín a liekov. Od januára 2026 sa časť potravín presunula z 19 % do základnej sadzby. Presné zoznamy a aktuálny stav sú na stránke Finančnej správy.
Sadzbu preto nikdy nepíš priamo do vzorca. Daj ju do samostatnej bunky s formátom percent a vo vzorci na ňu odkazuj. Keď sa sadzba zmení, prepíšeš jedno číslo.
Štyri vzorce na DPH
V B1 je cena, v B2 sadzba, napríklad 23 %.
- Cena s DPH z ceny bez DPH:
=B1*(1+B2) - DPH z ceny bez DPH:
=B1*B2 - Cena bez DPH z ceny s DPH:
=B1/(1+B2) - DPH obsiahnutá v cene s DPH:
=B1-B1/(1+B2)
Kde je vo vzorci 1+B2, daj ho do zátvoriek. Excel by inak najprv násobil alebo delil a až potom
pripočítal sadzbu.
Prečo nestačí odpočítať 23 %
Daň sa počíta z ceny bez DPH. Pri cene s DPH 123 € je cena bez DPH 100 € a daň 23 €. Odpočítaním 23 % zo 123 €
by vyšlo 94,71 €, čo je zle. Z ceny s DPH sa preto vždy delí: =B1/(1+B2).
Zaokrúhlenie na centy
Výsledok často vyjde s viac ako dvoma desatinnými miestami. Formát bunky ich skryje, ale Excel s nimi ďalej
počíta a súčty potom nemusia sedieť s faktúrou. Ceny preto zaokrúhli funkciou
ROUND: =ROUND(B1*(1+B2);2).
Príklady
Cena bez DPH z bločku
=B1/(1+B2) | A | B | |
|---|---|---|
| 1 | Cena s DPH (€) | 36,90 |
| 2 | Sadzba DPH | 23% |
| 3 | ||
| 4 | Bez DPH (€) | 30,00 |
Daň obsiahnutá v cene so zníženou sadzbou
Ubytovanie za 210 € s DPH 5 %. Koľko z toho je daň?
=ROUND(B1-B1/(1+B2);2) | A | B | |
|---|---|---|
| 1 | Cena s DPH (€) | 210,00 |
| 2 | Sadzba DPH | 5% |
| 3 | ||
| 4 | Z toho DPH (€) | 10,00 |
Časté chyby a čo znamenajú
Cena bez DPH vyjde nižšia, než má
Od ceny s DPH sa odpočítalo 23 %. Správne je ju vydeliť: =B1/(1+B2).
Cena s DPH vyjde len o pár centov vyššia
Chýbajú zátvorky: =B1*1+B2 pripočíta k cene len 0,23. Správne je =B1*(1+B2).
Pri skopírovanom vzorci je DPH nula
Odkaz na bunku so sadzbou sa pri kopírovaní posunul na prázdnu bunku. Ukotvi ho znakmi $: $B$7.
Viac v lekcii Absolútne a relatívne odkazy.
Súčet faktúry nesedí o cent
Jednotlivé ceny nie sú zaokrúhlené na centy, ďalšie desatinné miesta len skrýva formát. Použi ROUND pri každej položke.
Cvičenia
Päť úloh od ľahkých po náročnejšie. Vzorec píš do vyznačenej bunky, kontrolu spustíš klávesom Enter alebo tlačidlom Skontrolovať. Kontrola vzorec vyskúša aj s inými sadzbami.
Cvičenie 1: Koľko je DPH
ľahkáNotebook stojí bez DPH 680 €. Do B4 napíš vzorec, ktorý vypočíta, koľko eur bude DPH so sadzbou z B2.
| A | B | |
|---|---|---|
| 1 | Cena bez DPH (€) | 680,00 |
| 2 | Sadzba DPH | 23% |
| 3 | ||
| 4 | DPH (€) |
Klikni na bunku a jej adresa sa vloží do vzorca.
Riešenie: =B1*B2
680 × 0,23 = 156,40 €. Sadzba je v bunke, takže pri tovare s inou sadzbou stačí zmeniť B2.
Cvičenie 2: Cena bez DPH
strednáNa bločku je cena s DPH. Do B4 napíš vzorec, ktorý z nej vypočíta cenu bez DPH.
| A | B | |
|---|---|---|
| 1 | Cena s DPH (€) | 49,20 |
| 2 | Sadzba DPH | 23% |
| 3 | ||
| 4 | Cena bez DPH (€) |
Klikni na bunku a jej adresa sa vloží do vzorca.
Riešenie: =B1/(1+B2)
49,20 / 1,23 = 40 €. Odpočítať 23 % z ceny s DPH nestačí, lebo daň sa počítala z nižšej sumy, z ceny bez DPH.
Cvičenie 3: Rôzne sadzby
strednáNa faktúre sú položky s rôznymi sadzbami DPH. Do D2 napíš vzorec pre cenu s DPH so sadzbou z toho istého riadku. Vzorec sa skopíruje do D3 až D5.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Položka | Bez DPH | Sadzba | S DPH |
| 2 | Kniha | 18,00 | 5% | |
| 3 | Elektrina | 74,00 | 19% | |
| 4 | Slúchadlá | 59,00 | 23% | |
| 5 | Ubytovanie | 120,00 | 5% |
Klikni na bunku a jej adresa sa vloží do vzorca. Bunky s prerušovaným okrajom ukážu, čo vzorec vypočíta po skopírovaní.
Riešenie: =B2*(1+C2)
V D3 vznikne =B3*(1+C3), elektrina so sadzbou 19 %. Keby bola sadzba ukotvená ako $C$2, všetky položky by dostali 5 %.
Cvičenie 4: Na centy
náročnejšiaKaviareň počíta ceny s DPH zo sadzby v B7. Do C2 napíš vzorec, ktorý vypočíta cenu s DPH zaokrúhlenú na centy. Vzorec sa skopíruje do C3 až C5.
| A | B | C | |
|---|---|---|---|
| 1 | Položka | Bez DPH (€) | S DPH (€) |
| 2 | Espresso | 1,79 | |
| 3 | Cappuccino | 2,39 | |
| 4 | Limonáda | 2,99 | |
| 5 | Džús | 2,19 | |
| 6 | |||
| 7 | Sadzba DPH | 19% |
Klikni na bunku a jej adresa sa vloží do vzorca. Bunky s prerušovaným okrajom ukážu, čo vzorec vypočíta po skopírovaní.
Riešenie: =ROUND(B2*(1+$B$7);2)
1,79 × 1,19 = 2,1301. ROUND z toho urobí 2,13 € a s touto sumou sa ďalej naozaj počíta, nielen sa tak ukazuje.
Cvičenie 5: DPH obsiahnutá v cene
náročnejšiaNa pokladničnom doklade je len cena s DPH. Do B4 napíš vzorec, ktorý vypočíta, koľko z nej tvorí DPH, zaokrúhlené na centy.
| A | B | |
|---|---|---|
| 1 | Cena s DPH (€) | 100,00 |
| 2 | Sadzba DPH | 23% |
| 3 | ||
| 4 | Z toho DPH (€) |
Klikni na bunku a jej adresa sa vloží do vzorca.
Riešenie: =ROUND(B1-B1/(1+B2);2)
Cena bez DPH je 100 / 1,23, po zaokrúhlení 81,30 €, takže daň je 18,70 €. Rovnako funguje =ROUND(B1*B2/(1+B2);2).
Otázky a odpovede
Aký je vzorec na DPH v Exceli?
Cena s DPH je =cena*(1+sadzba), samotná DPH =cena*sadzba. Sadzbu daj do bunky
s formátom percent a vo vzorci na ňu odkazuj.
Ako vypočítať cenu bez DPH?
Cenu s DPH vydeľ súčtom jednotky a sadzby: =B1/(1+B2). Pri sadzbe 23 % je to delenie
číslom 1,23.
Ako vypočítať DPH zo sumy s DPH?
Od sumy odčítaj cenu bez DPH: =B1-B1/(1+B2). Rovnaký výsledok dá =B1*B2/(1+B2).
Výsledok zaokrúhli na centy funkciou ROUND.
Má Excel funkciu na DPH?
Nemá a nepotrebuje ju. Výpočet DPH je obyčajné počítanie s percentami, stačí násobenie a delenie.