Priemer v Exceli: funkcie AVERAGE, MIN a MAX
AVERAGE vypočíta priemer, MIN nájde najmenšie a MAX najväčšie číslo v rozsahu. Naučíš sa, ako narábajú s prázdnymi bunkami a nulami a ako vypočítať vážený priemer.
Vyskúšaj si to: Priemerná známka
Do bunky B7 napíš =AVERAGE(B2:B5) a stlač Enter. Excel vypočíta priemer známok z matematiky.
| A | B | |
|---|---|---|
| 1 | Písomka | Známka |
| 2 | September | 2 |
| 3 | Október | 1 |
| 4 | November | 3 |
| 5 | December | 1 |
| 6 | ||
| 7 | Priemer |
Klikni na bunku a jej adresa sa vloží do vzorca.
Riešenie: =AVERAGE(B2:B5)
AVERAGE(B2:B5) sčíta štyri známky a vydelí ich štyrmi: (2+1+3+1)/4 = 1,75.
Ako funguje funkcia AVERAGE
=AVERAGE(číslo1; [číslo2]; …)
AVERAGE počíta aritmetický priemer: čísla sčíta a vydelí ich počtom. Argumentom je najčastejšie jeden
rozsah, napríklad =AVERAGE(B2:B20). Môžeš ich zadať aj viac, oddelených bodkočiarkou, najviac 255.
V rozsahu AVERAGE vynechá prázdne bunky, text a logické hodnoty. Nuly však započíta. Prázdna bunka teda znamená „údaj chýba“, nula „výsledok bol nula“. Pri známkach či meraniach je to podstatný rozdiel.
Ako fungujú funkcie MIN a MAX
=MIN(číslo1; [číslo2]; …)
=MAX(číslo1; [číslo2]; …)
MIN vráti najmenšie číslo, MAX najväčšie. Prázdne bunky a text v rozsahu vynechajú. Keď v rozsahu nie je
žiadne číslo, vrátia 0. Povedia len hodnotu, nie to, v ktorom riadku je. Na to sa hodí
XLOOKUP: =XLOOKUP(MAX(B2:B7);B2:B7;A2:A7) vráti mesiac
s najvyššou tržbou, keď sú mesiace v stĺpci A a tržby v stĺpci B.
Priemer verzus medián
Keď je v údajoch jedna veľmi vysoká alebo nízka hodnota, priemer sa ňou posunie. Medián je prostredná hodnota
po zoradení a takéto výkyvy ho neovplyvnia. Pri platoch piatich ľudí 1 100, 1 200, 1 250, 1 300 a 6 000 €
je priemer 2 170 €, hoci štyria zarábajú okolo 1 200 €. Medián
=MEDIAN(B2:B6) vráti 1 250 €, čo lepšie opisuje bežný plat.
Rýchly priemer bez vzorca
Keď označíš bunky s číslami, Excel ukáže ich priemer, počet a súčet v stavovom riadku dole v okne. Do tabuľky ich však nezapíše. Na karte Domov je aj šípka pri tlačidle Automatický súčet, ktorá vloží priemer, minimum alebo maximum ako vzorec.
Príklady
Priemerná spotreba
Spotreba auta v litroch na 100 km za štyri tankovania.
=AVERAGE(B2:B5) | A | B | |
|---|---|---|
| 1 | Tankovanie | l/100 km |
| 2 | Marec | 6,4 |
| 3 | Apríl | 5,9 |
| 4 | Máj | 6,1 |
| 5 | Jún | 5,6 |
| 6 | ||
| 7 | Priemer: | 6,00 |
Najnižšia cena
Ten istý tovar v troch obchodoch. MIN nájde najlacnejšiu ponuku.
=MIN(B2:B4) | A | B | |
|---|---|---|
| 1 | Obchod | Cena (€) |
| 2 | Obchod A | 349,00 |
| 3 | Obchod B | 329,90 |
| 4 | Obchod C | 338,00 |
| 5 | ||
| 6 | Najlacnejšie: | 329,90 |
Priemer bez núl
Predajňa bola niektoré dni zatvorená a v tie dni má tržbu 0. Priemernú tržbu za otvorené dni vypočíta AVERAGEIF s podmienkou „nerovná sa nule“.
=AVERAGEIF(B2:B6;"<>0") | A | B | |
|---|---|---|
| 1 | Deň | Tržba (€) |
| 2 | Pondelok | 0 |
| 3 | Utorok | 840 |
| 4 | Streda | 910 |
| 5 | Štvrtok | 0 |
| 6 | Piatok | 1180 |
| 7 | ||
| 8 | Priemer: | 976,67 |
Časté chyby a čo znamenajú
Chyba #DIV/0!
V rozsahu nie je žiadne číslo, takže AVERAGE nemá čím deliť. Skontroluj, či rozsah obsahuje správne bunky a či čísla nie sú uložené ako text.
Priemer vychádza nižší, než by mal
V rozsahu sú nuly namiesto prázdnych buniek. Ak nula znamená „údaj chýba“, bunku vymaž alebo použi
AVERAGEIF s podmienkou "<>0".
Priemer počítaný ručne
=SUM(B2:B7)/6 bude vždy deliť šiestimi, aj keď niektorá bunka zostane prázdna. AVERAGE si počet
čísel zistí sama.
Priemer priemerov
Keď má jedna trieda 30 žiakov a druhá 12, priemer ich dvoch priemerov nie je priemer všetkých žiakov. Treba vážený priemer, ktorý si vyskúšaš v piatom cvičení.
Cvičenia
Päť úloh od ľahkých po náročnejšie. Vzorec píš do vyznačenej bunky, kontrolu spustíš klávesom Enter alebo tlačidlom Skontrolovať. Kontrola vzorec vyskúša aj na iných číslach.
Cvičenie 1: Najlepší mesiac
ľahkáPekáreň v Trenčíne má tržby za prvý polrok. Do B9 napíš vzorec, ktorý nájde najvyššiu mesačnú tržbu.
| A | B | |
|---|---|---|
| 1 | Mesiac | Tržba (€) |
| 2 | Január | 18420 |
| 3 | Február | 16950 |
| 4 | Marec | 19780 |
| 5 | Apríl | 21340 |
| 6 | Máj | 20115 |
| 7 | Jún | 22860 |
| 8 | ||
| 9 | Najvyššia tržba |
Klikni na bunku a jej adresa sa vloží do vzorca.
Riešenie: =MAX(B2:B7)
MAX(B2:B7) prejde všetkých šesť tržieb a vráti najväčšiu. Ktorý mesiac to bol, MAX nepovie, vráti len hodnotu.
Cvičenie 2: Rozdiel cenových ponúk
strednáObec dostala päť ponúk na opravu chodníka. Do B8 napíš jeden vzorec, ktorý vypočíta rozdiel medzi najdrahšou a najlacnejšou ponukou.
| A | B | |
|---|---|---|
| 1 | Firma | Ponuka (€) |
| 2 | Stavby Kupec | 48600 |
| 3 | Cesta plus | 52300 |
| 4 | Dlažby Hron | 45900 |
| 5 | Mestavia | 61200 |
| 6 | Chodníky Tatry | 49800 |
| 7 | ||
| 8 | Rozdiel (€) |
Klikni na bunku a jej adresa sa vloží do vzorca.
Riešenie: =MAX(B2:B6)-MIN(B2:B6)
MAX(B2:B6) vráti 61 200 €, MIN(B2:B6) 45 900 €. Rozdiel 15 300 € ukazuje, ako veľmi sa ponuky líšia.
Cvičenie 3: Priemer bez chýbajúceho testu
strednáMarek vynechal jeden test, bunka je prázdna. Do B9 napíš vzorec, ktorý vypočíta priemer bodov len z testov, ktoré písal.
| A | B | |
|---|---|---|
| 1 | Test | Body |
| 2 | Test 1 | 78 |
| 3 | Test 2 | 85 |
| 4 | Test 3 | |
| 5 | Test 4 | 69 |
| 6 | Test 5 | 0 |
| 7 | Test 6 | 92 |
| 8 | ||
| 9 | Priemer |
Klikni na bunku a jej adresa sa vloží do vzorca.
Riešenie: =AVERAGE(B2:B7)
AVERAGE(B2:B7) sčíta päť čísel a vydelí piatimi, prázdnu B4 vynechá. Nula v B6 je skutočný výsledok testu, preto sa počíta.
Cvičenie 4: Koľko chýba na víťaza
strednáNa školských pretekoch v hode loptičkou zisti pri každom žiakovi, o koľko metrov zaostal za najlepším hodom. Do C2 napíš vzorec, ktorý sa skopíruje do C3 až C6.
| A | B | C | |
|---|---|---|---|
| 1 | Žiak | Hod (m) | Za víťazom (m) |
| 2 | Tadeáš | 41,5 | |
| 3 | Michaela | 38 | |
| 4 | Samuel | 47,2 | |
| 5 | Nina | 35,8 | |
| 6 | Daniel | 44,1 |
Klikni na bunku a jej adresa sa vloží do vzorca. Bunky s prerušovaným okrajom ukážu, čo vzorec vypočíta po skopírovaní.
Riešenie: =MAX($B$2:$B$6)-B2
MAX($B$2:$B$6) je vo všetkých riadkoch rovnaký, lebo rozsah je ukotvený. Mení sa len B2 na B3, B4… Víťaz Samuel má v stĺpci C nulu.
Cvičenie 5: Vážený priemer
náročnejšiaZnámka z predmetu sa ráta z troch častí s rôznou váhou: písomky 50 %, projekt 30 %, ústna skúška 20 %. Do B6 napíš vzorec pre vážený priemer bodov. Obyčajný priemer by váhy nebral do úvahy.
| A | B | C | |
|---|---|---|---|
| 1 | Časť | Body | Váha |
| 2 | Písomky | 72 | 50% |
| 3 | Projekt | 90 | 30% |
| 4 | Ústna skúška | 65 | 20% |
| 5 | |||
| 6 | Vážený priemer |
Klikni na bunku a jej adresa sa vloží do vzorca.
Riešenie: =SUMPRODUCT(B2:B4;C2:C4)/SUM(C2:C4)
SUMPRODUCT vynásobí 72·0,5 + 90·0,3 + 65·0,2 = 76. Delenie súčtom váh (100 %) zabezpečí, že vzorec funguje, aj keď váhy dokopy nedajú 100 %. Platí aj =B2*C2+B3*C3+B4*C4, keď váhy dávajú spolu 100 %.
Otázky a odpovede
Ako vypočítať priemer v Exceli?
Do prázdnej bunky napíš =AVERAGE(, označ myšou bunky s číslami, uzavri zátvorku a stlač Enter.
Vznikne vzorec, napríklad =AVERAGE(B2:B20).
Ako sa volá funkcia priemer v slovenskom Exceli?
AVERAGE. Názvy funkcií sú v slovenskom Exceli anglické, české PRŮMĚR nefunguje. Argumenty oddeľuje bodkočiarka.
Ako vypočítať vážený priemer?
Funkciou SUMPRODUCT: =SUMPRODUCT(B2:B4;C2:C4)/SUM(C2:C4), kde v B sú hodnoty a v C ich váhy.
SUMPRODUCT vynásobí dvojice a súčiny sčíta, delenie súčtom váh dá priemer.
Ako nájsť najväčšie a najmenšie číslo?
Najväčšie nájde =MAX(B2:B20), najmenšie =MIN(B2:B20). Druhé najväčšie vráti
=LARGE(B2:B20;2), druhé najmenšie =SMALL(B2:B20;2).